cpplint.cmake

#-------------------------------------------------------------------------------
# Project Phoenix
#
# Copyright (c) 2017 RWTH Aachen University, Germany,
# Virtual Reality & Immersive Visualisation Group.
#-------------------------------------------------------------------------------
#                                  License
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#     http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#-------------------------------------------------------------------------------

find_package(PythonInterp 2.7 REQUIRED)
if(NOT PYTHON_EXECUTABLE)
  message(SEND_ERROR
    " ERROR: Could not find any python interpreter.
        Having a python interpreter is a mandatory requirement for cpplint.
        CMake will not generate the project without it. ")
endif()
if(NOT (PYTHON_VERSION_MAJOR EQUAL 2 AND PYTHON_VERSION_MINOR EQUAL 7))
  message(SEND_ERROR
    " ERROR: Did not find python 2.7.
        Having python 2.7 is a mandatory requirement for cpplint.
        CMake will not generate the project without it. ")  
endif()

set(CONAN_CPPLINT_DIR)
if(TARGET CONAN_PKG::cpplint)
  # TODO(@tvierjahn) think about a better way of getting the cpplint directory
  get_property(CONAN_CPPLINT_DIR
    TARGET CONAN_PKG::cpplint
    PROPERTY INTERFACE_INCLUDE_DIRECTORIES
    )
  #This path might contain generator expressions, which we do not need here
  if(CONAN_INCLUDE_DIRS_CPPLINT_RELEASE)
	set(CONAN_CPPLINT_DIR ${CONAN_INCLUDE_DIRS_CPPLINT_RELEASE})
  endif()
  if(EXISTS "${CONAN_CPPLINT_DIR}/cpplint.py")
    set(CPPLINT_COMMAND "${CONAN_CPPLINT_DIR}/cpplint.py")
  endif()
else()
  message("No cpplint found through conan, try to find an installed one on the system")
  find_file(CPPLINT_COMMAND cpplint.py
    PATHS $ENV{PATH} $ENV{CPPLINT_DIR}
  )
  if(NOT CPPLINT_COMMAND)
  message(SEND_ERROR
    " ERROR: Could not find cpplint.py.
        Having cpplint.py is a mandatory requirement.
        CMake will not generate the project without it.
        Add its location to the environments variables PATH or CPPLINT_DIR.")
  endif()
endif()

function(ADD_TEST_CPPLINT)
  set(options )
  set(oneValueArgs NAME)
  set(multiValueArgs )
  cmake_parse_arguments(ADD_TEST_CPPLINT
    "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN} )

  if(MSVC)
    set(CPPLINT_OUTPUT "--output=vs7")
  else()
    set(CPPLINT_OUTPUT "")
  endif()

  add_test(NAME "${ADD_TEST_CPPLINT_NAME}"
    COMMAND ${PYTHON_EXECUTABLE} ${CPPLINT_COMMAND} ${CPPLINT_OUTPUT}
    ${ADD_TEST_CPPLINT_UNPARSED_ARGUMENTS}
    )
  set_tests_properties(${ADD_TEST_CPPLINT_NAME} PROPERTIES TIMEOUT 7.0)
endfunction()